initial commit 0.3.x + leaf decay + saplings

CMakeLists.txt

@@ -0,0 +1,123 @@
+cmake_minimum_required(VERSION 2.6)
+if(${CMAKE_VERSION} STREQUAL "2.8.2")
+  # bug http://vtk.org/Bug/view.php?id=11020
+  message( WARNING "CMake/CPack version 2.8.2 will not create working .deb packages!")
+endif(${CMAKE_VERSION} STREQUAL "2.8.2")
+
+# This can be read from ${PROJECT_NAME} after project() is called
+project(minetest)
+
+# Also remember to set PROTOCOL_VERSION in clientserver.h when releasing
+set(VERSION_MAJOR 0)
+set(VERSION_MINOR 3)
+set(VERSION_PATCH 1)
+set(VERSION_STRING "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
+
+MESSAGE(STATUS "*** Will build version ${VERSION_STRING} ***")
+
+# Configuration options
+
+if(WIN32)
+	set(RUN_IN_PLACE 1 CACHE BOOL "Run directly in source directory structure")
+else()
+	set(RUN_IN_PLACE 0 CACHE BOOL "Run directly in source directory structure")
+endif()
+
+set(BUILD_CLIENT 1 CACHE BOOL "Build client")
+if(WIN32)
+	set(BUILD_SERVER 0 CACHE BOOL "Build server")
+else()
+	set(BUILD_SERVER 1 CACHE BOOL "Build server")
+endif()
+
+set(WARN_ALL 1 CACHE BOOL "Enable -Wall for Release build")
+
+if(NOT CMAKE_BUILD_TYPE)
+	# Default to release
+	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type: Debug or Release" FORCE)
+endif()
+
+# Included stuff
+set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
+include(${CMAKE_SOURCE_DIR}/cmake/Modules/misc.cmake)
+
+# This is done here so that relative search paths are more reasnable
+find_package(Irrlicht)
+
+#
+# Installation
+#
+
+if(WIN32)
+	set(DATADIR "data")
+	set(BINDIR "bin")
+	set(DOCDIR "doc")
+	set(EXAMPLE_CONF_DIR ".")
+elseif(APPLE)
+	# random placeholders
+	set(DATADIR "share/${PROJECT_NAME}")
+	set(BINDIR "bin")
+	set(DOCDIR "share/doc/${PROJECT_NAME}")
+	set(EXAMPLE_CONF_DIR ".")
+elseif(UNIX) # Linux, BSD etc
+	set(DATADIR "share/${PROJECT_NAME}")
+	set(BINDIR "bin")
+	set(DOCDIR "share/doc/${PROJECT_NAME}")
+	set(EXAMPLE_CONF_DIR "share/doc/${PROJECT_NAME}")
+endif()
+
+install(FILES "README.txt" DESTINATION "${DOCDIR}")
+install(FILES "doc/changelog.txt" DESTINATION "${DOCDIR}")
+install(FILES "minetest.conf.example" DESTINATION "${DOCDIR}")
+
+#
+# Subdirectories
+# Be sure to add all relevant definitions above this
+#
+
+add_subdirectory(src)
+
+# CPack
+
+set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "An InfiniMiner/Minecraft inspired game")
+set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
+set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
+set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
+set(CPACK_PACKAGE_VENDOR "celeron55")
+set(CPACK_PACKAGE_CONTACT "Perttu Ahola <celeron55@gmail.com>")
+
+if(WIN32)
+	# For some reason these aren't copied otherwise
+	# NOTE: For some reason now it seems to work without these
+	#if(BUILD_CLIENT)
+	#	install(FILES bin/minetest.exe DESTINATION bin)
+	#endif()
+	#if(BUILD_SERVER)
+	#	install(FILES bin/minetestserver.exe DESTINATION bin)
+	#endif()
+
+	set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32")
+
+	set(CPACK_GENERATOR ZIP)
+
+	# This might be needed for some installer
+	#set(CPACK_PACKAGE_EXECUTABLES bin/minetest.exe "Minetest" bin/minetestserver.exe "Minetest Server")
+elseif(APPLE)
+	# TODO
+	# see http://cmake.org/Wiki/CMake:CPackPackageGenerators#Bundle_.28OSX_only.29
+	#
+	set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-osx")
+	set(CPACK_PACKAGE_ICON "")
+	set(CPACK_BUNDLE_NAME ${PROJECT_NAME})
+	set(CPACK_BUNDLE_ICON "")
+	set(CPACK_BUNDLE_PLIST "")
+	set(CPACK_BUNDLE_STARTUP_COMMAND "Contents/MacOS/${PROJECT_NAME}")
+	set(CPACK_GENERATOR "Bundle")
+else()
+	set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-linux")
+	set(CPACK_GENERATOR TGZ)
+	set(CPACK_SOURCE_GENERATOR TGZ)
+endif()
+
+include(CPack)
+

README.txt

@@ -0,0 +1,278 @@
+Minetest-c55
+---------------
+An InfiniMiner/Minecraft inspired game.
+Copyright (c) 2010-2011 Perttu Ahola <celeron55@gmail.com>
+(see source files for other contributors)
+
+Further documentation:
+----------------------
+- Website: http://celeron.55.lt/~celeron55/minetest/
+- Wiki: http://celeron.55.lt/~celeron55/minetest/wiki/
+- Forum: http://celeron.55.lt/~celeron55/minetest/forum/
+- doc/ directory of source distribution
+
+This game is not finished:
+--------------------------
+- Don't expect it to work as well as a finished game will.
+- Please report any bugs to me. debug.txt is useful.
+
+Controls:
+---------
+- See the in-game pause menu
+- Settable in the configuration file, see the section below.
+
+Map directory:
+--------------
+- Map is stored in a directory, which can be removed to generate a new map.
+- There is a command-line option for it: --map-dir
+- For a RUN_IN_PLACE build, it is located in:
+		../world
+- Otherwise something like this:
+	Windows: C:\Documents and Settings\user\Application Data\minetest\world
+	Linux: ~/.minetest/world
+	OS X: ~/Library/Application Support/minetest/world
+
+Configuration file:
+-------------------
+- An optional configuration file can be used. See minetest.conf.example.
+- Path to file can be passed as a parameter to the executable:
+	--config <path-to-file>
+- Defaults:
+	- If built with -DRUN_IN_PLACE=1:
+		../minetest.conf
+		../../minetest.conf
+	- Otherwise something like this:
+		Windows: C:\Documents and Settings\user\Application Data\minetest\minetest.conf
+		Linux: ~/.minetest/minetest.conf
+		OS X: ~/Library/Application Support/minetest.conf
+
+Command-line options:
+---------------------
+- Use --help
+
+Compiling on GNU/Linux:
+-----------------------
+
+Install dependencies. Here's an example for Debian/Ubuntu:
+$ apt-get install build-essential libirrlicht-dev cmake libbz2-dev libpng12-dev libjpeg8-dev libxxf86vm-dev libgl1-mesa-dev libsqlite3-dev
+
+Download source, extract (this is the URL to the latest of source repository, which might not work at all times):
+$ wget https://github.com/celeron55/minetest/tarball/master -O master.tar.gz
+$ tar xf master.tar.gz
+$ cd celeron55-minetest-286edd4 (or similar)
+
+Build a version that runs directly from the source directory:
+$ cmake . -DRUN_IN_PLACE=1
+$ make -j2
+
+Run it:
+$ cd bin
+$ ./minetest
+
+- Use cmake . -LH to see all CMake options and their current state
+- If you want to install it system-wide (or are making a distribution package), you will want to use -DRUN_IN_PLACE=0
+- You can build a bare server or a bare client by specifying -DBUILD_CLIENT=0 or -DBUILD_SERVER=0
+- You can select between Release and Debug build by -DCMAKE_BUILD_TYPE=<Debug or Release>
+  - Debug build is slower, but gives much more useful output in a debugger
+
+Compiling on Windows:
+---------------------
+
+- You need:
+	* CMake:
+		http://www.cmake.org/cmake/resources/software.html
+	* MinGW or Visual Studio
+		http://www.mingw.org/
+		http://msdn.microsoft.com/en-us/vstudio/default
+	* Irrlicht SDK 1.7:
+		http://irrlicht.sourceforge.net/downloads.html
+	* Zlib headers (zlib125.zip)
+		http://www.winimage.com/zLibDll/index.html
+	* Zlib library (zlibwapi.lib and zlibwapi.dll from zlib125dll.zip):
+		http://www.winimage.com/zLibDll/index.html
+	* Optional: gettext bibrary and tools:
+		http://gnuwin32.sourceforge.net/downlinks/gettext.php
+		- This is used for other UI languages. Feel free to leave it out.
+	* And, of course, Minetest-c55:
+		http://celeron.55.lt/~celeron55/minetest/download
+- Steps:
+	- Select a directory called DIR hereafter in which you will operate.
+	- Make sure you have CMake and a compiler installed.
+	- Download all the other stuff to DIR and extract them into there.
+	  ("extract here", not "extract to packagename/")
+	- All those packages contain a nice base directory in them, which
+	  should end up being the direct subdirectories of DIR.
+	- You will end up with a directory structure like this (+=dir, -=file):
+	-----------------
+	+ DIR
+		- zlib-1.2.5.tar.gz
+		- zlib125dll.zip
+		- irrlicht-1.7.1.zip
+		- 110214175330.zip (or whatever, this is the minetest source)
+		+ zlib-1.2.5
+			- zlib.h
+			+ win32
+			...
+		+ zlib125dll
+			- readme.txt
+			+ dll32
+			...
+		+ irrlicht-1.7.1
+			+ lib
+			+ include
+			...
+		+ gettext (optional)
+			+bin
+			+include
+			+lib
+		+ minetest
+			+ src
+			+ doc
+			- CMakeLists.txt
+			...
+	-----------------
+	- Start up the CMake GUI
+	- Select "Browse Source..." and select DIR/minetest
+	- Now, if using MSVC:
+		- Select "Browse Build..." and select DIR/minetest-build
+	- Else if using MinGW:
+		- Select "Browse Build..." and select DIR/minetest
+	- Select "Configure"
+	- Select your compiler
+	- It will warn about missing stuff, ignore that at this point. (later don't)
+	- Make sure the configuration is as follows
+	  (note that the versions may differ for you):
+	-----------------
+	BUILD_CLIENT             [X]
+	BUILD_SERVER             [ ]
+	CMAKE_BUILD_TYPE         Release
+	CMAKE_INSTALL_PREFIX     DIR/minetest-install
+	IRRLICHT_SOURCE_DIR      DIR/irrlicht-1.7.1
+	RUN_IN_PLACE             [X]
+	WARN_ALL                 [ ]
+	ZLIB_DLL                 DIR/zlib125dll/dll32/zlibwapi.dll
+	ZLIB_INCLUDE_DIR         DIR/zlib-1.2.5
+	ZLIB_LIBRARIES           DIR/zlib125dll/dll32/zlibwapi.lib
+	GETTEXT_BIN_DIR          DIR/gettext/bin
+	GETTEXT_INCLUDE_DIR      DIR/gettext/include
+	GETTEXT_LIBRARIES        DIR/gettext/lib/intl.lib
+	GETTEXT_MSGFMT           DIR/gettext/bin/msgfmt
+	-----------------
+	- Hit "Configure"
+	- Hit "Configure" once again 8)
+	- If something is still coloured red, you have a problem.
+	- Hit "Generate"
+	If using MSVC:
+		- Open the generated minetest.sln
+		- The project defaults to the "Debug" configuration. Make very sure to
+		  select "Release", unless you want to debug some stuff (it's slower
+		  and might not even work at all)
+		- Build the ALL_BUILD project
+		- Build the INSTALL project
+		- You should now have a working game with the executable in
+			DIR/minetest-install/bin/minetest.exe
+		- Additionally you may create a zip package by building the PACKAGE
+		  project.
+	If using MinGW:
+		- Using the command line, browse to the build directory and run 'make'
+		  (or mingw32-make or whatever it happens to be)
+		- You should now have a working game with the executable in
+			DIR/minetest/bin/minetest.exe
+
+Windows releases of minetest are built using a bat script like this:
+--------------------------------------------------------------------
+
+set installpath="C:\tmp\minetest_install"
+set irrlichtpath="C:\tmp\irrlicht-1.7.2"
+
+set sourcedir=%CD%
+set builddir=%sourcedir%\bvc10
+mkdir %builddir%
+pushd %builddir%
+cmake %sourcedir% -G "Visual Studio 10" -DIRRLICHT_SOURCE_DIR=%irrlichtpath% -DRUN_IN_PLACE=1 -DCMAKE_INSTALL_PREFIX=%installpath%
+"C:\WINDOWS\Microsoft.NET\Framework\v4.0.30319\MSBuild.exe" ALL_BUILD.vcxproj /p:Configuration=Release
+"C:\WINDOWS\Microsoft.NET\Framework\v4.0.30319\MSBuild.exe" INSTALL.vcxproj /p:Configuration=Release
+"C:\WINDOWS\Microsoft.NET\Framework\v4.0.30319\MSBuild.exe" PACKAGE.vcxproj /p:Configuration=Release
+popd
+
+License of Minetest-c55 textures
+--------------------------------
+
+This does not apply to texture packs made by others.
+
+Attribution-ShareAlike 3.0 Unported (CC BY-SA 3.0)                                 
+http://creativecommons.org/licenses/by-sa/3.0/
+
+License of Minetest-c55
+-----------------------
+
+Minetest-c55
+Copyright (C) 2010-2011 celeron55, Perttu Ahola <celeron55@gmail.com>
+
+This program is free software; you can redistribute it and/or modify
+it under the terms of the GNU General Public License as published by
+the Free Software Foundation; either version 2 of the License, or
+(at your option) any later version.
+
+This program is distributed in the hope that it will be useful,
+but WITHOUT ANY WARRANTY; without even the implied warranty of
+MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+GNU General Public License for more details.
+
+You should have received a copy of the GNU General Public License along
+with this program; if not, write to the Free Software Foundation, Inc.,
+51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
+
+Irrlicht
+---------------
+
+This program uses the Irrlicht Engine. http://irrlicht.sourceforge.net/
+
+ The Irrlicht Engine License
+
+Copyright © 2002-2005 Nikolaus Gebhardt
+
+This software is provided 'as-is', without any express or implied
+warranty. In no event will the authors be held liable for any damages
+arising from the use of this software.
+
+Permission is granted to anyone to use this software for any purpose,
+including commercial applications, and to alter it and redistribute
+it freely, subject to the following restrictions:
+
+   1. The origin of this software must not be misrepresented; you
+      must not claim that you wrote the original software. If you use
+	  this software in a product, an acknowledgment in the product
+	  documentation would be appreciated but is not required.
+   2. Altered source versions must be plainly marked as such, and must
+      not be misrepresented as being the original software.
+   3. This notice may not be removed or altered from any source
+      distribution.
+
+
+JThread
+---------------
+
+This program uses the JThread library. License for JThread follows:
+
+Copyright (c) 2000-2006  Jori Liesenborgs (jori.liesenborgs@gmail.com)
+
+Permission is hereby granted, free of charge, to any person obtaining a
+copy of this software and associated documentation files (the "Software"),
+to deal in the Software without restriction, including without limitation
+the rights to use, copy, modify, merge, publish, distribute, sublicense,
+and/or sell copies of the Software, and to permit persons to whom the
+Software is furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included
+in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
+OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
+THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
+IN THE SOFTWARE.
+
+

cmake/Modules/FindGettextLib.cmake

@@ -0,0 +1,72 @@
+# Package finder for gettext libs and include files
+
+SET(CUSTOM_GETTEXT_PATH "${PROJECT_SOURCE_DIR}/../../gettext"
+	CACHE FILEPATH "path to custom gettext")
+
+# by default
+SET(GETTEXT_FOUND FALSE)
+
+FIND_PATH(GETTEXT_INCLUDE_DIR
+	NAMES libintl.h
+	PATHS "${CUSTOM_GETTEXT_PATH}/include"
+	DOC "gettext include directory")
+
+FIND_PROGRAM(GETTEXT_MSGFMT
+	NAMES msgfmt
+	PATHS "${CUSTOM_GETTEXT_PATH}/bin"
+	DOC "path to msgfmt")
+
+# modern Linux, as well as Mac, seem to not need require special linking
+# they do not because gettext is part of glibc
+# TODO check the requirements on other BSDs and older Linux
+IF (WIN32)
+	IF(MSVC)
+		SET(GETTEXT_LIB_NAMES
+			libintl.lib intl.lib libintl3.lib intl3.lib)
+	ELSE()
+		SET(GETTEXT_LIB_NAMES
+			libintl.dll.a intl.dll.a libintl3.dll.a intl3.dll.a)
+	ENDIF()
+	FIND_LIBRARY(GETTEXT_LIBRARY
+		NAMES ${GETTEXT_LIB_NAMES}
+		PATHS "${CUSTOM_GETTEXT_PATH}/lib"
+		DOC "gettext *intl*.lib")
+	FIND_FILE(GETTEXT_DLL
+		NAMES libintl.dll intl.dll libintl3.dll intl3.dll
+		PATHS "${CUSTOM_GETTEXT_PATH}/bin" "${CUSTOM_GETTEXT_PATH}/lib" 
+		DOC "gettext *intl*.dll")
+	FIND_FILE(GETTEXT_ICONV_DLL
+		NAMES libiconv2.dll
+		PATHS "${CUSTOM_GETTEXT_PATH}/bin" "${CUSTOM_GETTEXT_PATH}/lib"
+		DOC "gettext *iconv*.lib")
+ENDIF(WIN32)
+
+IF(GETTEXT_INCLUDE_DIR AND GETTEXT_MSGFMT)
+	IF (WIN32)
+		# in the Win32 case check also for the extra linking requirements
+		IF(GETTEXT_LIBRARY AND GETTEXT_DLL AND GETTEXT_ICONV_DLL)
+			SET(GETTEXT_FOUND TRUE)
+		ENDIF()
+	ELSE(WIN32)
+		# *BSD variants require special linkage as they don't use glibc
+		IF(${CMAKE_SYSTEM_NAME} MATCHES "BSD")
+			SET(GETTEXT_LIBRARY "intl")
+		ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "BSD")
+		SET(GETTEXT_FOUND TRUE)
+	ENDIF(WIN32)
+ENDIF()
+
+IF(GETTEXT_FOUND)
+	SET(GETTEXT_PO_PATH ${CMAKE_SOURCE_DIR}/po)
+	SET(GETTEXT_MO_BUILD_PATH ${CMAKE_BINARY_DIR}/locale/<locale>/LC_MESSAGES)
+	SET(GETTEXT_MO_DEST_PATH ${DATADIR}/../locale/<locale>/LC_MESSAGES)
+	FILE(GLOB GETTEXT_AVAILABLE_LOCALES RELATIVE ${GETTEXT_PO_PATH} "${GETTEXT_PO_PATH}/*")
+	LIST(REMOVE_ITEM GETTEXT_AVAILABLE_LOCALES minetest.pot)
+	MACRO(SET_MO_PATHS _buildvar _destvar _locale)
+		STRING(REPLACE "<locale>" ${_locale} ${_buildvar} ${GETTEXT_MO_BUILD_PATH})
+		STRING(REPLACE "<locale>" ${_locale} ${_destvar} ${GETTEXT_MO_DEST_PATH})
+	ENDMACRO(SET_MO_PATHS)
+ELSE()
+	SET(GETTEXT_INCLUDE_DIR "")
+	SET(GETTEXT_LIBRARY "")
+ENDIF()

cmake/Modules/FindIrrlicht.cmake

@@ -0,0 +1,94 @@
+#FindIrrlicht.cmake
+
+set(IRRLICHT_SOURCE_DIR "" CACHE PATH "Path to irrlicht source directory (optional)")
+
+if( UNIX )
+	# Unix
+else( UNIX )
+	# Windows
+endif( UNIX )
+
+# Find include directory
+
+if(NOT IRRLICHT_SOURCE_DIR STREQUAL "")
+	set(IRRLICHT_SOURCE_DIR_INCLUDE
+		"${IRRLICHT_SOURCE_DIR}/include"
+	)
+
+	set(IRRLICHT_LIBRARY_NAMES libIrrlicht.a Irrlicht Irrlicht.lib)
+
+	if(WIN32)
+		if(MSVC)
+			set(IRRLICHT_SOURCE_DIR_LIBS "${IRRLICHT_SOURCE_DIR}/lib/Win32-visualstudio")
+			set(IRRLICHT_LIBRARY_NAMES Irrlicht.lib)
+		else()
+			set(IRRLICHT_SOURCE_DIR_LIBS "${IRRLICHT_SOURCE_DIR}/lib/Win32-gcc")
+			set(IRRLICHT_LIBRARY_NAMES libIrrlicht.a libIrrlicht.dll.a)
+		endif()
+	else()
+		set(IRRLICHT_SOURCE_DIR_LIBS "${IRRLICHT_SOURCE_DIR}/lib/Linux")
+		set(IRRLICHT_LIBRARY_NAMES libIrrlicht.a)
+	endif()
+
+	FIND_PATH(IRRLICHT_INCLUDE_DIR NAMES irrlicht.h
+		PATHS
+		${IRRLICHT_SOURCE_DIR_INCLUDE}
+		NO_DEFAULT_PATH
+	)
+
+	FIND_LIBRARY(IRRLICHT_LIBRARY NAMES ${IRRLICHT_LIBRARY_NAMES}
+		PATHS
+		${IRRLICHT_SOURCE_DIR_LIBS}
+		NO_DEFAULT_PATH
+	)
+
+else()
+
+	FIND_PATH(IRRLICHT_INCLUDE_DIR NAMES irrlicht.h
+		PATHS
+		/usr/local/include/irrlicht
+		/usr/include/irrlicht
+	)
+
+	FIND_LIBRARY(IRRLICHT_LIBRARY NAMES libIrrlicht.a Irrlicht
+		PATHS
+		/usr/local/lib
+		/usr/lib
+	)
+endif()
+
+MESSAGE(STATUS "IRRLICHT_SOURCE_DIR = ${IRRLICHT_SOURCE_DIR}")
+MESSAGE(STATUS "IRRLICHT_INCLUDE_DIR = ${IRRLICHT_INCLUDE_DIR}")
+MESSAGE(STATUS "IRRLICHT_LIBRARY = ${IRRLICHT_LIBRARY}")
+
+# On windows, find the dll for installation
+if(WIN32)
+	if(MSVC)
+		FIND_FILE(IRRLICHT_DLL NAMES Irrlicht.dll
+			PATHS
+			"${IRRLICHT_SOURCE_DIR}/bin/Win32-VisualStudio"
+			DOC "Path of the Irrlicht dll (for installation)"
+		)
+	else()
+		FIND_FILE(IRRLICHT_DLL NAMES Irrlicht.dll
+			PATHS
+			"${IRRLICHT_SOURCE_DIR}/bin/Win32-gcc"
+			DOC "Path of the Irrlicht dll (for installation)"
+		)
+	endif()
+	MESSAGE(STATUS "IRRLICHT_DLL = ${IRRLICHT_DLL}")
+endif(WIN32)
+
+# handle the QUIETLY and REQUIRED arguments and set IRRLICHT_FOUND to TRUE if
+# all listed variables are TRUE
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(IRRLICHT DEFAULT_MSG IRRLICHT_LIBRARY IRRLICHT_INCLUDE_DIR)
+
+IF(IRRLICHT_FOUND)
+  SET(IRRLICHT_LIBRARIES ${IRRLICHT_LIBRARY})
+ELSE(IRRLICHT_FOUND)
+  SET(IRRLICHT_LIBRARIES)
+ENDIF(IRRLICHT_FOUND)
+
+MARK_AS_ADVANCED(IRRLICHT_LIBRARY IRRLICHT_INCLUDE_DIR IRRLICHT_DLL) 
+

cmake/Modules/FindJthread.cmake

@@ -0,0 +1,18 @@
+# Look for jthread, use our own if not found
+
+FIND_PATH(JTHREAD_INCLUDE_DIR jthread.h)
+
+FIND_LIBRARY(JTHREAD_LIBRARY NAMES jthread)
+
+IF(JTHREAD_LIBRARY AND JTHREAD_INCLUDE_DIR)
+	SET( JTHREAD_FOUND TRUE )
+ENDIF(JTHREAD_LIBRARY AND JTHREAD_INCLUDE_DIR)
+
+IF(JTHREAD_FOUND)
+	MESSAGE(STATUS "Found system jthread header file in ${JTHREAD_INCLUDE_DIR}")
+	MESSAGE(STATUS "Found system jthread library ${JTHREAD_LIBRARY}")
+ELSE(JTHREAD_FOUND)
+	SET(JTHREAD_INCLUDE_DIR ${PROJECT_SOURCE_DIR}/jthread)
+	SET(JTHREAD_LIBRARY jthread)
+	MESSAGE(STATUS "Using project jthread library")
+ENDIF(JTHREAD_FOUND)

cmake/Modules/FindSqlite3.cmake

@@ -0,0 +1,18 @@
+# Look for sqlite3, use our own if not found
+
+FIND_PATH(SQLITE3_INCLUDE_DIR sqlite3.h)
+
+FIND_LIBRARY(SQLITE3_LIBRARY NAMES sqlite3)
+
+IF(SQLITE3_LIBRARY AND SQLITE3_INCLUDE_DIR)
+	SET( SQLITE3_FOUND TRUE )
+ENDIF(SQLITE3_LIBRARY AND SQLITE3_INCLUDE_DIR)
+
+IF(SQLITE3_FOUND)
+	MESSAGE(STATUS "Found system sqlite3 header file in ${SQLITE3_INCLUDE_DIR}")
+	MESSAGE(STATUS "Found system sqlite3 library ${SQLITE3_LIBRARY}")
+ELSE(SQLITE3_FOUND)
+	SET(SQLITE3_INCLUDE_DIR ${PROJECT_SOURCE_DIR}/sqlite)
+	SET(SQLITE3_LIBRARY sqlite3)
+	MESSAGE(STATUS "Using project sqlite3 library")
+ENDIF(SQLITE3_FOUND)

cmake/Modules/misc.cmake

@@ -0,0 +1,21 @@
+#
+# Random macros
+#
+
+# Not used ATM
+
+MACRO (GETDATETIME RESULT)
+    IF (WIN32)
+		EXECUTE_PROCESS(COMMAND "cmd" /C echo %date% %time% OUTPUT_VARIABLE ${RESULT})
+		string(REGEX REPLACE "\n" "" ${RESULT} "${${RESULT}}")
+    ELSEIF(UNIX)
+        EXECUTE_PROCESS(COMMAND "date" "+%Y-%m-%d_%H:%M:%S" OUTPUT_VARIABLE ${RESULT})
+		string(REGEX REPLACE "\n" "" ${RESULT} "${${RESULT}}")
+    ELSE (WIN32)
+        MESSAGE(SEND_ERROR "date not implemented")
+        SET(${RESULT} "Unknown")
+    ENDIF (WIN32)
+
+	string(REGEX REPLACE " " "_" ${RESULT} "${${RESULT}}")
+ENDMACRO (GETDATETIME)
+